Background

Here I am with a Network Logon, but no corresponding Fullname.

Windows AD Tools

Depending on the version of Windows, we can quickly put together a script for getting the information.

      dsquery user -name joe | dsget user -display

If invalid username, you will get :

    dsget failed:'Target object for this command' is missing

If valid user, you will get something such as :

  display
  Adeniji, Daniel

Code

VBScript

Here is a VBscript for doing same:

 

Option Explicit
Dim strADDomain
Dim strUserName
Dim strUserNameCurrent
Dim objWshShell
Dim strObjectData
Dim strNameNotFound
Dim iCommandLineArgCount
Dim objUser

Const CommandLineArgCountExpected = 1
Const ERR_InvalidProcedureCallORArgument = 5

Const OBJECT_REF_SYNTAX = "WinNT://{0}/{1}"
Const ERR_NAME_NOT_FOUND = "Not not found Domain {0} / User {1}"

rem SQL string formatting in VBScript
rem PEOPLE AREN'T LOOKING FOR WEBSITES, THEY'RE LOOKING FOR ANSWERS.
rem http://lutrov.com/blog/sql-string-formatting-in-vbscript
function fmt(str, args())
   dim res, i
   res = str
   for i = 0 to ubound(args)
      res = replace(res, chr(123) & cstr(i) & chr(125), cstr(args(i)))
   next
   fmt = res
end function

REM *******************************************************************
Rem MS Windows Shell Environment Variables
REM *******************************************************************
Set objWshShell = WScript.CreateObject( "WScript.Shell" )

	strADDomain = objWshShell.ExpandEnvironmentStrings( "%USERDOMAIN%" )

	strUserNameCurrent = objWshShell.ExpandEnvironmentStrings( "%USERNAME%" )

set objWSHShell = Nothing

REM *******************************************************************
Rem Get Command Line Arguments
REM *******************************************************************
iCommandLineArgCount = WScript.Arguments.Count

if (iCommandLineArgCount = CommandLineArgCountExpected) Then

	strUserName = WScript.Arguments.Item(0)

else

	Err.Raise ERR_InvalidProcedureCallORArgument ' Invalid procedure call or argument

end if

REM *******************************************************************
Rem If arguments not passed in, then assume for current user
REM *******************************************************************
if (strUserName = "") Then

	strUserName = strUserNameCurrent

end if

rem strObjectData = "WinNT://" & strADDomain & "/" & strUserName
strObjectData = fmt(OBJECT_REF_SYNTAX, array(strADDomain, strUserName))

rem (null): The network path was not found.
on error resume next

	Set objUser = GetObject(strObjectData)

on error goto 0

rem display full name
if IsObject(objUser) Then

	Wscript.Echo objUser.FullName

else

	strNameNotFound = fmt(ERR_NAME_NOT_FOUND, array(strADDomain, strUserName))

	Wscript.Echo strNameNotFound

end if	

rem free object
if IsObject(objUser) Then

	Set objUser = Nothing

end if

To try things out:

    cscript getUserFullName.vbs dadeniji

References

VBScript

• Microsoft / Tutorial & References
  • How Can I Get the Full Name of a Windows NT 4.0 User When All I Have is Their Logon Name?
    http://blogs.technet.com/b/heyscriptingguy/archive/2007/02/15/how-can-i-get-the-full-name-of-a-windows-nt-4-0-user-when-all-i-have-is-their-logon-name.aspx
  • Working with Command-Line Arguments
    https://technet.microsoft.com/en-us/library/ee156618.aspx
  • VBScript Run-time Errors
    https://msdn.microsoft.com/en-us/library/xe43cc8d.aspx

• 3rd Party Blogs & Q/A:
  • String Formatting (by Ivan Lutrov )
    http://lutrov.com/blog/sql-string-formatting-in-vbscript
  • Check if an Object exists in VBScript
    http://stackoverflow.com/questions/4100506/check-if-an-object-exists-in-vbscript

Summary

How poetic justice is that?

I bemoaned “On error resume next”, Microsoft – Classic ASP – Error Suppressed, barely a week gone by.  And, now I need it to avoid a missing AD Entry warning.

But, nevertheless when used, quickly close it out with an “on error goto 0“.